home *** CD-ROM | disk | FTP | other *** search
/ Chip 2007 January, February, March & April / Chip-Cover-CD-2007-02.iso / Pakiet bezpieczenstwa / mini Pentoo LiveCD 2006.1 / mpentoo-2006.1.iso / livecd.squashfs / usr / share / aclocal-1.7 / init.m4 < prev    next >
Encoding:
M4 Source File  |  2005-10-16  |  4.4 KB  |  125 lines
  1. # Do all the work for Automake.                            -*- Autoconf -*-
  2.  
  3. # This macro actually does too much some checks are only needed if
  4. # your package does certain things.  But this isn't really a big deal.
  5.  
  6. # Copyright (C) 1996, 1997, 1998, 1999, 2000, 2001, 2002, 2003
  7. # Free Software Foundation, Inc.
  8.  
  9. # This program is free software; you can redistribute it and/or modify
  10. # it under the terms of the GNU General Public License as published by
  11. # the Free Software Foundation; either version 2, or (at your option)
  12. # any later version.
  13.  
  14. # This program is distributed in the hope that it will be useful,
  15. # but WITHOUT ANY WARRANTY; without even the implied warranty of
  16. # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  17. # GNU General Public License for more details.
  18.  
  19. # You should have received a copy of the GNU General Public License
  20. # along with this program; if not, write to the Free Software
  21. # Foundation, Inc., 59 Temple Place - Suite 330, Boston, MA
  22. # 02111-1307, USA.
  23.  
  24. # serial 10
  25.  
  26. AC_PREREQ([2.54])
  27.  
  28. # Autoconf 2.50 wants to disallow AM_ names.  We explicitly allow
  29. # the ones we care about.
  30. m4_pattern_allow([^AM_[A-Z]+FLAGS$])dnl
  31.  
  32. # AM_INIT_AUTOMAKE(PACKAGE, VERSION, [NO-DEFINE])
  33. # AM_INIT_AUTOMAKE([OPTIONS])
  34. # -----------------------------------------------
  35. # The call with PACKAGE and VERSION arguments is the old style
  36. # call (pre autoconf-2.50), which is being phased out.  PACKAGE
  37. # and VERSION should now be passed to AC_INIT and removed from
  38. # the call to AM_INIT_AUTOMAKE.
  39. # We support both call styles for the transition.  After
  40. # the next Automake release, Autoconf can make the AC_INIT
  41. # arguments mandatory, and then we can depend on a new Autoconf
  42. # release and drop the old call support.
  43. AC_DEFUN([AM_INIT_AUTOMAKE],
  44. [AC_REQUIRE([AM_SET_CURRENT_AUTOMAKE_VERSION])dnl
  45.  AC_REQUIRE([AC_PROG_INSTALL])dnl
  46. # test to see if srcdir already configured
  47. if test "`cd $srcdir && pwd`" != "`pwd`" &&
  48.    test -f $srcdir/config.status; then
  49.   AC_MSG_ERROR([source directory already configured; run "make distclean" there first])
  50. fi
  51.  
  52. # test whether we have cygpath
  53. if test -z "$CYGPATH_W"; then
  54.   if (cygpath --version) >/dev/null 2>/dev/null; then
  55.     CYGPATH_W='cygpath -w'
  56.   else
  57.     CYGPATH_W=echo
  58.   fi
  59. fi
  60. AC_SUBST([CYGPATH_W])
  61.  
  62. # Define the identity of the package.
  63. dnl Distinguish between old-style and new-style calls.
  64. m4_ifval([$2],
  65. [m4_ifval([$3], [_AM_SET_OPTION([no-define])])dnl
  66.  AC_SUBST([PACKAGE], [$1])dnl
  67.  AC_SUBST([VERSION], [$2])],
  68. [_AM_SET_OPTIONS([$1])dnl
  69.  AC_SUBST([PACKAGE], ['AC_PACKAGE_TARNAME'])dnl
  70.  AC_SUBST([VERSION], ['AC_PACKAGE_VERSION'])])dnl
  71.  
  72. _AM_IF_OPTION([no-define],,
  73. [AC_DEFINE_UNQUOTED(PACKAGE, "$PACKAGE", [Name of package])
  74.  AC_DEFINE_UNQUOTED(VERSION, "$VERSION", [Version number of package])])dnl
  75.  
  76. # Some tools Automake needs.
  77. AC_REQUIRE([AM_SANITY_CHECK])dnl
  78. AC_REQUIRE([AC_ARG_PROGRAM])dnl
  79. AM_MISSING_PROG(ACLOCAL, aclocal-${am__api_version})
  80. AM_MISSING_PROG(AUTOCONF, autoconf)
  81. AM_MISSING_PROG(AUTOMAKE, automake-${am__api_version})
  82. AM_MISSING_PROG(AUTOHEADER, autoheader)
  83. AM_MISSING_PROG(MAKEINFO, makeinfo)
  84. AM_MISSING_PROG(AMTAR, tar)
  85. AM_PROG_INSTALL_SH
  86. AM_PROG_INSTALL_STRIP
  87. # We need awk for the "check" target.  The system "awk" is bad on
  88. # some platforms.
  89. AC_REQUIRE([AC_PROG_AWK])dnl
  90. AC_REQUIRE([AC_PROG_MAKE_SET])dnl
  91. AC_REQUIRE([AM_SET_LEADING_DOT])dnl
  92.  
  93. _AM_IF_OPTION([no-dependencies],,
  94. [AC_PROVIDE_IFELSE([AC_PROG_CC],
  95.                   [_AM_DEPENDENCIES(CC)],
  96.                   [define([AC_PROG_CC],
  97.                           defn([AC_PROG_CC])[_AM_DEPENDENCIES(CC)])])dnl
  98. AC_PROVIDE_IFELSE([AC_PROG_CXX],
  99.                   [_AM_DEPENDENCIES(CXX)],
  100.                   [define([AC_PROG_CXX],
  101.                           defn([AC_PROG_CXX])[_AM_DEPENDENCIES(CXX)])])dnl
  102. ])
  103. ])
  104.  
  105.  
  106. # When config.status generates a header, we must update the stamp-h file.
  107. # This file resides in the same directory as the config header
  108. # that is generated.  The stamp files are numbered to have different names.
  109.  
  110. # Autoconf calls _AC_AM_CONFIG_HEADER_HOOK (when defined) in the
  111. # loop where config.status creates the headers, so we can generate
  112. # our stamp files there.
  113. AC_DEFUN([_AC_AM_CONFIG_HEADER_HOOK],
  114. [# Compute $1's index in $config_headers.
  115. _am_stamp_count=1
  116. for _am_header in $config_headers :; do
  117.   case $_am_header in
  118.     $1 | $1:* )
  119.       break ;;
  120.     * )
  121.       _am_stamp_count=`expr $_am_stamp_count + 1` ;;
  122.   esac
  123. done
  124. echo "timestamp for $1" >`AS_DIRNAME([$1])`/stamp-h[]$_am_stamp_count])
  125.